Crappy hot reloading of textures and Properties editor for textures

GlitchyEditor/src/AssetFile.bf

@@ -30,6 +30,8 @@ class AssetFile
 
 	private bool _isDirectory;
 
+	private Object _loadedAsset;
+
 	public bool IsDirectory => _isDirectory;
 
 	public StringView FilePath => _path;
@@ -38,6 +40,8 @@ class AssetFile
 
 	public AssetConfig AssetConfig => _assetConfig;
 
+	public Object LoadedAsset => _loadedAsset;
+
 	[AllowAppend]
 	public this(EditorContentManager contentManager, StringView path, bool isDirectory)
 	{
@@ -102,10 +106,12 @@ class AssetFile
 		}
 	}
 
-	private void SaveAssetConfig()
+	public void SaveAssetConfig()
 	{
 		gBonEnv.serializeFlags |= .Verbose;
 
 		Bon.SerializeIntoFile(_assetConfig, _assetConfigPath);
+
+		_assetConfig.Config.[Friend]_changed = false;
 	}
 }

GlitchyEditor/src/Assets/TextureAssetLoader.bf

@@ -7,14 +7,155 @@ using GlitchyEngine.Content;
 using GlitchyEngine.Renderer;
 using GlitchyEngine.Math;
 using DirectXTK;
+using ImGui;
 
 namespace GlitchyEditor.Assets;
 
+abstract class AssetPropertiesEditor
+{
+	private AssetFile _asset;
+
+	public AssetFile Asset => _asset;
+
+	public this(AssetFile asset)
+	{
+		_asset = asset;
+	}
+
+	public abstract void ShowEditor();
+}
+
+
+class TextureAssetPropertiesEditor : AssetPropertiesEditor
+{
+	EditorTextureAssetLoaderConfig _textureConfig;
+
+	public this(AssetFile asset) : base(asset)
+	{
+		_textureConfig = asset.AssetConfig.Config as EditorTextureAssetLoaderConfig;
+	}
+
+	static char8*[3] _filterFuncNames = char8*[]("Point", "Linear", "Anisotropic");
+
+	public override void ShowEditor()
+	{
+		if (_textureConfig == null)
+			return;
+
+		bool generateMips = _textureConfig.GenerateMipMaps;
+		if (ImGui.Checkbox("Generate Mip Maps", &generateMips))
+			_textureConfig.GenerateMipMaps = generateMips;
+
+		bool isSrgb = _textureConfig.IsSRGB;
+		if (ImGui.Checkbox("Is sRGB", &isSrgb))
+			_textureConfig.IsSRGB = isSrgb;
+
+		SamplerStateDescription samplerStateDescription = _textureConfig.SamplerStateDescription;
+
+		void ShowFilterCombo(String label, ref FilterFunction filterFunction)
+		{
+			int32 selectedFilter = filterFunction.Underlying;
+			if (ImGui.Combo(label, &selectedFilter, &_filterFuncNames, 3))
+				filterFunction = (.)selectedFilter;
+		}
+
+		ImGui.Separator();
+		ImGui.TextUnformatted("Texture Filtering:");
+		ImGui.Separator();
+		
+		ImGui.EnumCombo("Min Filter", ref samplerStateDescription.MinFilter);
+		ImGui.AttachTooltip("""
+			Sampling method used for minification.
+			If set to "Anisotropic" all Filters are set to "Anisotropic" internally.
+			""");
+		ImGui.EnumCombo("Mag Filter", ref samplerStateDescription.MagFilter);
+		ImGui.AttachTooltip("""
+			Sampling method used for magnification.
+			If set to "Anisotropic" all Filters are set to "Anisotropic" internally.
+			""");
+		ImGui.EnumCombo("Mip Map Filter", ref samplerStateDescription.MipFilter);
+		ImGui.AttachTooltip("""
+			Method used for mip-level sampling.
+			If set to "Anisotropic" all Filters are set to "Anisotropic" internally.
+			""");
+
+		if (samplerStateDescription.MagFilter == .Anisotropic ||
+			samplerStateDescription.MinFilter == .Anisotropic ||
+			samplerStateDescription.MipFilter == .Anisotropic)
+		{
+			ImGui.SliderScalar("Anisotropy Level", ref samplerStateDescription.MaxAnisotropy, 1, 16);
+		}
+
+		ImGui.NewLine();
+
+		ImGui.EnumCombo("Filter Mode", ref samplerStateDescription.FilterMode);
+		ImGui.AttachTooltip("Filtering method to use when sampling a texture.");
+
+		if (samplerStateDescription.FilterMode == .Comparison)
+		{
+			ImGui.EnumCombo("Comparison Function", ref samplerStateDescription.ComparisonFunction);
+			ImGui.AttachTooltip("""
+				The function that is used to compare the sampled data against the existing sampled data.
+				Only applies if Filter Mode is set to FilterMode.Comparison.
+				""");
+		}
+
+		ImGui.Separator();
+		ImGui.TextUnformatted("Wrapping");
+		ImGui.Separator();
+		
+		ImGui.EnumCombo("Wrap Mode U", ref samplerStateDescription.AddressModeU);
+		ImGui.AttachTooltip("Method to use for resolving a u texture coordinate that is outside the 0 to 1 range.");
+
+		ImGui.EnumCombo("Wrap Mode V", ref samplerStateDescription.AddressModeV);
+		ImGui.AttachTooltip("Method to use for resolving a v texture coordinate that is outside the 0 to 1 range.");
+
+		ImGui.EnumCombo("Wrap Mode W", ref samplerStateDescription.AddressModeW);
+		ImGui.AttachTooltip("Method to use for resolving a w texture coordinate that is outside the 0 to 1 range.");
+
+		if (samplerStateDescription.AddressModeU == .Border ||
+			samplerStateDescription.AddressModeV == .Border ||
+			samplerStateDescription.AddressModeW == .Border)
+		{
+			ImGui.ColorEdit4("Border Color", ref samplerStateDescription.BorderColor);
+		}
+		
+		ImGui.Separator();
+		ImGui.TextUnformatted("Mip Maps");
+		ImGui.Separator();
+		
+		ImGui.DragFloat("Mip LOD Bias", &samplerStateDescription.MipLODBias, 0.1f);
+		ImGui.AttachTooltip("""
+			Offset from the calculated mipmap level.
+			For example, if the GPU calculates that a texture should be sampled at mipmap level 3 and "Mip LOD Bias" is 2, then the texture will be sampled at mipmap level 5.
+			""");
+		
+		ImGui.DragFloat("Min Mip LOD", &samplerStateDescription.MipMinLOD);
+		ImGui.AttachTooltip("Lower end of the mipmap range to clamp access to, where 0 is the largest and most detailed mipmap level and any level higher than that is less detailed.");
+		
+		ImGui.DragFloat("Max LOD Bias", &samplerStateDescription.MipMaxLOD);
+		ImGui.AttachTooltip("""
+			Upper end of the mipmap range to clamp access to, where 0 is the largest and most detailed mipmap level and any level higher than that is less detailed.
+			This value must be greater than or equal to "Min Mip LOD". To have no upper limit on LOD set this to a large value.
+			""");
+
+		_textureConfig.SamplerStateDescription = samplerStateDescription;
+	}
+
+	public static AssetPropertiesEditor Factory(AssetFile assetFile)
+	{
+		return new TextureAssetPropertiesEditor(assetFile);
+	}
+}
+
 [BonTarget, BonPolyRegister]
 class EditorTextureAssetLoaderConfig : AssetLoaderConfig
 {
 	[BonInclude]
 	private bool _generateMipMaps;
+	
+	[BonInclude]
+	private bool _isSrgb;
 
 	[BonInclude]
 	private SamplerStateDescription _samplerStateDescription = .();
@@ -24,6 +165,12 @@ class EditorTextureAssetLoaderConfig : AssetLoaderConfig
 		get => _generateMipMaps;
 		set => SetIfChanged(ref _generateMipMaps, value);
 	}
+	
+	public bool IsSRGB
+	{
+		get => _isSrgb;
+		set => SetIfChanged(ref _isSrgb, value);
+	}
 
 	public SamplerStateDescription SamplerStateDescription
 	{
@@ -32,7 +179,12 @@ class EditorTextureAssetLoaderConfig : AssetLoaderConfig
 	}
 }
 
-class EditorTextureAssetLoader : IAssetLoader
+interface IReloadingAssetLoader
+{
+	public void ReloadAsset(AssetFile assetFile, Stream data);
+}
+
+class EditorTextureAssetLoader : IAssetLoader, IReloadingAssetLoader
 {
 	private static readonly List<StringView> _fileExtensions = new .(){".png", ".dds"} ~ delete _; // ".jpg", ".bmp"
 
@@ -61,29 +213,33 @@ class EditorTextureAssetLoader : IAssetLoader
 	const String PngMagicWord = "\x89\x50\x4E\x47\x0D\x0A\x1A\x0A";
 	const String DdsMagicWord = "DDS ";
 
-	private static Texture LoadTexture(Stream data, EditorTextureAssetLoaderConfig config)
+	enum TextureType
 	{
-		Debug.Profiler.ProfileResourceFunction!();
+		Unknown,
+		DDS,
+		PNG
+	}
 
+	private static TextureType GetTextureType(Stream data)
+	{
+		int64 position = data.Position;
+		
 		var readResult = data.Read<char8[8]>();
 
-		data.Position = 0;
-
+		data.Position = position;
+		
 		char8[8] magicWord;
-
-		Texture texture = null;
-
 		if (readResult case .Ok(out magicWord))
 		{
 			StringView strView = .(&magicWord, magicWord.Count);
 
 			if (strView.StartsWith(PngMagicWord))
 			{
-				texture = LoadPng(data, config);
+				return .PNG;
 			}
 			else if (strView.StartsWith(DdsMagicWord))
 			{
-				texture = LoadDds(data, config);
+				return .DDS;
 			}
 			else
 			{
@@ -91,28 +247,82 @@ class EditorTextureAssetLoader : IAssetLoader
 			}
 		}
 
+		return .Unknown;
+	}
+
+	private static Texture LoadTexture(Stream data, EditorTextureAssetLoaderConfig config)
+	{
+		Debug.Profiler.ProfileResourceFunction!();
+		
+		Texture texture = null;
+
+		switch(GetTextureType(data))
+		{
+		case .DDS:
+			texture = LoadDds(data, config);
+		case .PNG:
+			texture = LoadPng(data, config);
+		case .Unknown:
+			Runtime.FatalError("Unknown image format.");
+		}
+
 		Log.EngineLogger.AssertDebug(texture != null);
 
-		/*SamplerStateDescription samplerDesc = .()
-		{
-			MinFilter = config.MinFilter,
-			MagFilter = config.MagFilter,
-			MipFilter = config.MipFilter,
-			AddressModeU = config.WrapModeU,
-			AddressModeV = config.WrapModeV,
-			AddressModeW = config.WrapModeW
-		};*/
-
-		SamplerState sam = SamplerStateManager.GetSampler(config.SamplerStateDescription);
-
-		texture.SamplerState = sam;
-
-		sam.ReleaseRef();
+		SetSampler(texture, config);
 
 		return texture;
 	}
 
-	private static Texture LoadPng(Stream data, EditorTextureAssetLoaderConfig config)
+	public void ReloadAsset(AssetFile assetFile, Stream data)
+	{
+		Texture reloadingTexture = assetFile.LoadedAsset as Texture;
+
+		if (reloadingTexture == null)
+		{
+			Log.EngineLogger.Error($"{nameof(Self)}: Requested reload of \"{assetFile.FilePath}\" but it's not a Texture!");
+			return;
+		}
+
+		EditorTextureAssetLoaderConfig config = assetFile.AssetConfig.Config as EditorTextureAssetLoaderConfig;
+		
+		if (config == null)
+		{
+			Log.EngineLogger.Error($"{nameof(Self)}: Config of asset \"{assetFile.FilePath}\" doesn't have the correct type!");
+			return;
+		}
+
+		switch(GetTextureType(data))
+		{
+		case .DDS:
+			ReloadDds(reloadingTexture as Texture2D, data, config);
+		case .PNG:
+			ReloadPng(reloadingTexture as Texture2D, data, config);
+		case .Unknown:
+			Runtime.FatalError("Unknown image format.");
+		}
+		
+		SetSampler(reloadingTexture, config);
+	}
+
+	private static void SetSampler(Texture texture, EditorTextureAssetLoaderConfig config)
+	{
+		using (SamplerState samplerState = SamplerStateManager.GetSampler(config.SamplerStateDescription))
+		{
+			texture.SamplerState = samplerState;
+		}
+	}
+
+	private static void ReloadPng(Texture2D reloadingTexture, Stream data, EditorTextureAssetLoaderConfig config)
+	{
+		Debug.Profiler.ProfileResourceFunction!();
+
+		using (Texture2D newTexture = LoadPng(data, config))
+		{
+			reloadingTexture.[Friend]SneakySwappyTexture(newTexture);
+		}
+	}
+
+	private static Texture2D LoadPng(Stream data, EditorTextureAssetLoaderConfig config)
 	{
 		Debug.Profiler.ProfileResourceFunction!();
 
@@ -134,7 +344,7 @@ class EditorTextureAssetLoader : IAssetLoader
 
 		// TODO: load as SRGB because PNGs are usually not stored as linear
 		//Texture2DDesc desc = .(width, height, srgb? .R8G8B8A8_UNorm_SRGB : .R8G8B8A8_UNorm, 1, 1, .Immutable);
-		Texture2DDesc desc = .(width, height, .R8G8B8A8_UNorm, 1, 1, .Immutable);
+		Texture2DDesc desc = .(width, height, config.IsSRGB ? .R8G8B8A8_UNorm_SRGB : .R8G8B8A8_UNorm, 1, 1, .Immutable);
 		Texture2D texture = new Texture2D(desc);
 		texture.SetData<Color>((.)rawData);
 
@@ -145,6 +355,14 @@ class EditorTextureAssetLoader : IAssetLoader
 		return texture;
 	}
 	
+	private static void ReloadDds(Texture2D reloadingTexture, Stream data, EditorTextureAssetLoaderConfig config)
+	{
+		using (Texture2D newTexture = new [Friend]Texture2D(data))
+		{
+			reloadingTexture.[Friend]SneakySwappyTexture(newTexture);
+		}
+	}
+
 	private static Texture LoadDds(Stream data, EditorTextureAssetLoaderConfig config)
 	{
 		Texture2D texture = new [Friend]Texture2D(data);

GlitchyEditor/src/EditWindows/ContentBrowserWindow.bf

@@ -14,7 +14,7 @@ namespace GlitchyEditor.EditWindows
 	class ContentBrowserWindow : EditorWindow
 	{
 		// TODO: Get from project
-		const String ContentDirectory  = "./content";
+		//const String ContentDirectory  = "./content";
 
 		private append String _currentDirectory = .();
 
@@ -25,6 +25,8 @@ namespace GlitchyEditor.EditWindows
 
 		public EditorContentManager _manager;
 
+		public StringView SelectedFile => _selectedFile;
+
 		public this(EditorContentManager contentManager)
 		{
 			_manager = contentManager;
@@ -191,8 +193,8 @@ namespace GlitchyEditor.EditWindows
 				String fullpath = scope String(entry->Path);
 
 				// TODO: this is dirty
-				if (fullpath.StartsWith(ContentDirectory, .OrdinalIgnoreCase))
-					fullpath.Remove(0, ContentDirectory.Length);
+				if (fullpath.StartsWith(_manager.ContentDirectory, .OrdinalIgnoreCase))
+					fullpath.Remove(0, _manager.ContentDirectory.Length);
 
 				ImGui.SetDragDropPayload("CONTENT_BROWSER_ITEM", fullpath.CStr(), (.)fullpath.Length, .Once);
 

GlitchyEditor/src/EditWindows/PropertiesWindow.bf

@@ -0,0 +1,86 @@
+using ImGui;
+using System;
+using GlitchyEngine.Collections;
+using GlitchyEngine.Content;
+using System.Reflection;
+using GlitchyEngine;
+using GlitchyEditor.Assets;
+
+namespace GlitchyEditor.EditWindows;
+
+class PropertiesWindow : EditorWindow
+{
+	private AssetPropertiesEditor _currentPropertiesEditor ~ delete _;
+
+	public this(Editor editor)
+	{
+		_editor = editor;
+	}
+
+	protected override void InternalShow()
+	{
+		defer { ImGui.End(); }
+		if(!ImGui.Begin("Properties", &_open, .None))
+			return;
+
+		ShowAssetProperties();
+	}
+
+	/// Gets the AssetFile for the asset currently selected in the ContentBrowserWindow
+	/// @returns the AssetFile for the currently selected asset of null, if no file is selected.
+	private AssetFile GetCurrentAssetFile()
+	{
+		StringView selectedFileName = _editor.ContentBrowserWindow.SelectedFile;
+
+		Result<TreeNode<AssetNode>> treeNode = _editor.ContentManager.AssetHierarchy.GetNodeFromPath(selectedFileName);
+
+		if (treeNode case .Ok(let assetNode))
+			return assetNode->AssetFile;
+		
+		return null;
+	}
+
+	private void ShowAssetProperties()
+	{
+		AssetFile assetFile = GetCurrentAssetFile();
+
+		if (_currentPropertiesEditor?.Asset != assetFile)
+		{
+			delete _currentPropertiesEditor;
+			_currentPropertiesEditor = _editor.ContentManager.GetNewPropertiesEditor(assetFile);
+		}	 
+
+		if (assetFile == null)
+			return;
+
+		// TODO: allow changing AssetLoader
+		// assetFile.AssetConfig.AssetLoade
+
+		// TODO: ignore file
+		/*ImGui.Checkbox("Ignore", &assetFile.AssetConfig.IgnoreFile);
+		
+		if (ImGui.IsItemHovered())
+			ImGui.SetTooltip("If checked this file will be ignored and not treated as an asset.");*/
+
+		ShowPropertiesEditor(assetFile);
+	}
+
+	private void ShowPropertiesEditor(AssetFile assetFile)
+	{
+		if (_currentPropertiesEditor == null)
+			return;
+		
+		_currentPropertiesEditor.ShowEditor();
+
+		if (!assetFile.AssetConfig.Config.Changed)
+		{
+			ImGui.BeginDisabled();
+			defer:: { ImGui.EndDisabled(); }
+		}
+		
+		ImGui.Separator();
+
+		if (ImGui.Button("Apply"))
+			assetFile.SaveAssetConfig();
+	}
+}

GlitchyEditor/src/Editor.bf

@@ -12,16 +12,14 @@ namespace GlitchyEditor
 	class Editor
 	{
 		private Scene _scene;
-		
+
+		private EditorContentManager _contentManager;
+
 		private EntityHierarchyWindow _entityHierarchyWindow ~ delete _;
 		private ComponentEditWindow _componentEditWindow ~ delete _;
-		private SceneViewportWindow _sceneViewportWindow = new .(this) ~ delete _;
+		private SceneViewportWindow _sceneViewportWindow~ delete _;
 		private ContentBrowserWindow _contentBrowserWindow ~ delete _;
-
-		public EntityHierarchyWindow EntityHierarchyWindow => _entityHierarchyWindow;
-		public ComponentEditWindow ComponentEditWindow => _componentEditWindow;
-		public SceneViewportWindow SceneViewportWindow => _sceneViewportWindow;
-		public ContentBrowserWindow ContentBrowserWindow => _contentBrowserWindow;
+		private PropertiesWindow _propertiesWindow ~ delete _;
 
 		public Scene CurrentScene
 		{
@@ -33,27 +31,43 @@ namespace GlitchyEditor
 			}
 		}
 
+		public EditorContentManager ContentManager => _contentManager;
+		
+		public EntityHierarchyWindow EntityHierarchyWindow => _entityHierarchyWindow;
+		public ComponentEditWindow ComponentEditWindow => _componentEditWindow;
+		public SceneViewportWindow SceneViewportWindow => _sceneViewportWindow;
+		public ContentBrowserWindow ContentBrowserWindow => _contentBrowserWindow;
+		public PropertiesWindow PropertiesWindow => _propertiesWindow;
+
 		public EditorCamera* CurrentCamera { get; set; }
 
 		public Event<EventHandler<StringView>> RequestOpenScene ~ _.Dispose();
 
 		/// Creates a new editor for the given world
-		public this(Scene scene)
+		public this(Scene scene, EditorContentManager contentManager)
 		{
+			_scene = scene;
+			_contentManager = contentManager;
+
+			InitWindows();
+		}
+
+		private void InitWindows()
+		{
+			_sceneViewportWindow = new SceneViewportWindow(this);
 			_entityHierarchyWindow = new EntityHierarchyWindow(this, _scene);
-			CurrentScene = scene;
-
 			_componentEditWindow = new ComponentEditWindow(_entityHierarchyWindow);
-
 			_contentBrowserWindow = new ContentBrowserWindow((.)Application.Get().ContentManager);
+			_propertiesWindow = new PropertiesWindow(this);
 		}
 
 		public void Update()
 		{
+			_sceneViewportWindow.Show();
 			_entityHierarchyWindow.Show();
 			_componentEditWindow.Show();
-			_sceneViewportWindow.Show();
 			_contentBrowserWindow.Show();
+			_propertiesWindow.Show();
 		}
 	}
 }

GlitchyEditor/src/EditorContentManager.bf

@@ -122,6 +122,7 @@ class AssetHierarchy
 		{
 			_contentDirectory.Clear();
 			_contentDirectory.Append(value);
+			Path.Fixup(_contentDirectory);
 		}
 	}
 
@@ -137,6 +138,8 @@ class AssetHierarchy
 		_fileSystemDirty = true;
 
 		SetupFileSystemWatcher();
+
+		Update();
 	}
 	
 	/// Initializes the FSW for the current ContentDirectory and registers the events.
@@ -151,7 +154,8 @@ class AssetHierarchy
 			
 			Log.EngineLogger.Trace($"File content changed (\"{filename}\")");
 			//_fileSystemDirty = true;
-			// TODO: Handle file changes (reload asset, etc...)
+
+			FileContentChanged(filename);
 		});
 
 		fsw.OnCreated.Add(new (filename) => {
@@ -262,6 +266,8 @@ class AssetHierarchy
 					assetNode.Name = new String();
 					Path.GetFileName(filepathBuffer, assetNode.Name);
 					
+					filepathBuffer.Replace(Path.AltDirectorySeparatorChar, Path.DirectorySeparatorChar);
+
 					assetNode.Path = new String(filepathBuffer);
 					assetNode.IsDirectory = false;
 
@@ -308,6 +314,8 @@ class AssetHierarchy
 		/// Recursively adds all Files and Subdirectories.
 		void AddDirectoryToTree(String path, TreeNode<AssetNode> parentNode)
 		{
+			path.Replace(Path.AltDirectorySeparatorChar, Path.DirectorySeparatorChar);
+
 			// Try to find the node for the specified path in the given parent
 			TreeNode<AssetNode> treeNode = parentNode.Children.Where(scope (node) => node.Value.Path == path).FirstOrDefault();
 
@@ -358,6 +366,40 @@ class AssetHierarchy
 
 		_fileSystemDirty = false;
 	}
+
+	private void FileContentChanged(StringView fileName)
+	{
+		var fileName;
+
+		// Config files aren't really tracked but changing them effectively changes the corresponding file
+		// so we fire the event for them.
+		if (fileName.EndsWith(AssetFile.ConfigFileExtension))
+			fileName.RemoveFromEnd(AssetFile.ConfigFileExtension.Length);
+
+		String fileNameWithContentRoot = scope .();
+		Path.InternalCombine(fileNameWithContentRoot, _contentDirectory, fileName);
+
+		var nodeResult = GetNodeFromPath(fileNameWithContentRoot);
+
+		TreeNode<AssetNode> node = null;
+
+		if (!(nodeResult case .Ok(out node)))
+		{
+			Log.EngineLogger.Error($"Could not find node for file \"{fileNameWithContentRoot}\"");
+		}
+
+		// Don't fire event for directories.
+		if (node->IsDirectory)
+			return;
+
+		OnFileContentChanged(node.Value);
+
+		// TODO: Handle file changes (reload asset, etc...)
+	}
+
+	public delegate void FileContentChangedFunc(AssetNode node);
+
+	public Event<FileContentChangedFunc> OnFileContentChanged ~ _.Dispose();
 }
 
 class EditorContentManager : IContentManager
@@ -379,12 +421,56 @@ class EditorContentManager : IContentManager
 
 	public this()
 	{
+		_assetHierarchy.OnFileContentChanged.Add(new => OnFileContentChanged);
+	}
+
+	private void OnFileContentChanged(AssetNode assetNode)
+	{
+		// Asset isn't loaded so we don't need to reload it.
+		if (assetNode.AssetFile.LoadedAsset == null)
+			return;
+
+		String neededAssetLoaderName = assetNode.AssetFile.AssetConfig?.AssetLoader;
+
+		if (String.IsNullOrWhiteSpace(neededAssetLoaderName))
+			return;
+
+		IAssetLoader assetLoader = null;
+
+		String loaderNameBuffer = scope String(64);
+
+		for (IAssetLoader loader in _assetLoaders)
+		{
+			loader.GetType().GetName(loaderNameBuffer..Clear());
+
+			if (loaderNameBuffer == neededAssetLoaderName)
+			{
+				assetLoader = loader;
+				break;
+			}
+		}
+
+		if (assetLoader == null)
+		{
+			Log.EngineLogger.Error($"Could not find asset loader \"{neededAssetLoaderName}\"");
+			return;
+		}
+
+		if (var assetReloader = assetLoader as IReloadingAssetLoader)
+		{
+			Stream stream = GetStream(assetNode.Path);
+
+			assetReloader.ReloadAsset(assetNode.AssetFile, stream);
+
+			delete stream;
+		}
 	}
 
 	public void SetContentDirectory(StringView contentDirectory)
 	{
 		_contentDirectory.Clear();
 		_contentDirectory.Append(contentDirectory);
+		Path.Fixup(_contentDirectory);
 
 		_assetHierarchy.SetContentDirectory(contentDirectory);
 	}
@@ -404,6 +490,12 @@ class EditorContentManager : IContentManager
 	private append List<String> _supportedExtensions = .() ~ ClearAndDeleteItems!(_);
 	private append List<IAssetLoader> _assetLoaders = .() ~ ClearAndDeleteItems!(_);
 	private append Dictionary<StringView, IAssetLoader> _defaultAssetLoaders = .();
+	private append Dictionary<String, function AssetPropertiesEditor(AssetFile)> _assetPropertiesEditors = .() ~ {
+		for (String key in _.Keys)
+		{
+			delete key;
+		}
+	};
 
 	public void RegisterAssetLoader<T>() where T : new, class, IAssetLoader
 	{
@@ -443,6 +535,30 @@ class EditorContentManager : IContentManager
 			}
 		}
 	}
+	
+	public void SetAssetPropertiesEditor(Type assetLoaderType, function AssetPropertiesEditor(AssetFile) editorFactory)
+	{
+		String loaderTypeName = new String();
+		assetLoaderType.GetName(loaderTypeName);
+
+		_assetPropertiesEditors[loaderTypeName] = editorFactory;
+	}
+
+	public void SetAssetPropertiesEditor<TAssetLoader>(function AssetPropertiesEditor(AssetFile) editorFactory) where TAssetLoader : IAssetLoader
+	{
+		SetAssetPropertiesEditor(typeof(TAssetLoader), editorFactory);
+	}
+
+	public AssetPropertiesEditor GetNewPropertiesEditor(AssetFile assetFile)
+	{
+		if (assetFile?.AssetConfig.AssetLoader == null)
+			return null;
+
+		if (_assetPropertiesEditors.TryGetValue(assetFile.AssetConfig.AssetLoader, let propertiesEditorfactory))
+			return propertiesEditorfactory(assetFile);
+
+		return null;
+	}
 
 	public bool IsLoaded(StringView identifier)
 	{
@@ -457,9 +573,19 @@ class EditorContentManager : IContentManager
 		}
 
 		String filePath = scope String(identifier.Length + _contentDirectory.Length + 2);
-		Path.InternalCombine(filePath, _contentDirectory, identifier);
+		Path.Combine(filePath, _contentDirectory, identifier);
 
-		AssetFile file = scope .(this, filePath, false);
+		Path.Fixup(filePath);
+
+		//filePath.Replace(Path.AltDirectorySeparatorChar, Path.DirectorySeparatorChar);
+
+		Result<TreeNode<AssetNode>> resultNode = AssetHierarchy.GetNodeFromPath(filePath);
+
+		if (resultNode case .Err)
+			Runtime.FatalError();
+
+		//AssetFile file = scope .(this, filePath, false);
+		AssetFile file = resultNode->Value.AssetFile;
 		
 		IAssetLoader assetLoader = null;
 
@@ -488,6 +614,8 @@ class EditorContentManager : IContentManager
 
 		delete stream;
 
+		file.[Friend]_loadedAsset = loadedAsset;
+
 		return loadedAsset;
 	}
 

GlitchyEditor/src/EditorLayer.bf

@@ -57,6 +57,8 @@ namespace GlitchyEditor
 
 		EditorIcons _editorIcons ~ _.ReleaseRef();
 
+		EditorContentManager _contentManager;
+
 		enum SceneState
 		{
 			Edit,
@@ -71,7 +73,7 @@ namespace GlitchyEditor
 		{
 			Application.Get().Window.IsVSync = false;
 
-			InitContentLoader();
+			InitContentManager();
 
 			InitGraphics();
 
@@ -83,15 +85,17 @@ namespace GlitchyEditor
 			NewScene();
 		}
 
-		private void InitContentLoader()
+		private void InitContentManager()
 		{
-			EditorContentManager contentManager = new EditorContentManager();
-			contentManager.SetContentDirectory("./content");
+			_contentManager = new EditorContentManager();
+			_contentManager.SetContentDirectory("./content");
 
-			contentManager.RegisterAssetLoader<EditorTextureAssetLoader>();
-			contentManager.SetAsDefaultAssetLoader<EditorTextureAssetLoader>(".png", ".dds");
+			_contentManager.RegisterAssetLoader<EditorTextureAssetLoader>();
+			_contentManager.SetAsDefaultAssetLoader<EditorTextureAssetLoader>(".png", ".dds");
+			_contentManager.SetAssetPropertiesEditor<EditorTextureAssetLoader>(=> TextureAssetPropertiesEditor.Factory);
 
-			Application.Get().[Friend]_contentManager = contentManager;
+			// Todo: Sketchy...
+			Application.Get().[Friend]_contentManager = _contentManager;
 		}
 
 		private void InitGraphics()
@@ -144,7 +148,7 @@ namespace GlitchyEditor
 
 		private void InitEditor()
 		{
-			_editor = new Editor(_scene);
+			_editor = new Editor(_scene, _contentManager);
 			_editor.SceneViewportWindow.ViewportSizeChanged.Add(new (s, e) => ViewportSizeChanged(s, e));
 			_editor.CurrentCamera = &_camera;